배치파일로 업데이트 알림 구현하기

드롭박스가 업로드한 파일 '갱신'을 지원하고, (같은 파일을 올리면 다운로드 링크가 변하지 않음)

wget을 이용하면 배치파일로 파일을 다운로드 받을 수 있다는점을 이용합니다.

 

준비물

드롭박스 계정

wget.exe

새로운 버전의 정보를 담은 배치파일 (예시 : VCHECK.cmd )

현재 배치파일 버전과 새 정보를 비교할 배치파일 (예시:업데이트 확인.cmd )

 

 

 

방법 

 

 

예시 배치파일(VCHECK)의 내용은 

set RELEASE_VER=1

입니다.

VCHECK.cmd를 드롭박스에 올리고 공유를 눌러 링크를 만듭니다.

회원 가입 과정이나 업로드 방법같은건 이런 강좌 읽을 사람에게 필요하다고 생각되지 않으므로 생략합니다.

 

드롭박스 링크는 https://www.dropbox.com/s/0000000000000/VCHECK.cmd?dl=0 과 같은 모양인데,

맨 끝 dl=0 을 dl=1로 바꿔줍니다. 그럼 드롭박스 사이트를 거치지 않고 즉시 다운로드가 가능합니다.

 

즉 https://www.dropbox.com/s/0000000000000/VCHECK.cmd?dl=1 과 같은 모양이 되겠죠.

 

 

그다음 업데이트 확인용 배치파일을 작성합니다. 

:: 배치파일이 위치한 경로로 실행 경로 변경하기

pushd %~dp0

 

:: nv.tag가 있으면 바로 새버전이 있다는 알림으로 보내기

IF EXIST nv.tag goto NEW

:: VCHECK.CMD가 이미 있으면 버전 체크 생략하기
IF EXIST VCHECK.cmd goto SKIP_VCHECK

 

:: 업로드한 VCHECK.cmd를 wget으로 다운로드하기

wget.exe -q --no-check-certificate -O VCHECK.CMD "https://www.dropbox.com/s/자신의드롭박스파일링크/VCHECK.cmd?dl=1"

 

:: 기본값 설정

set RELEASE_VER=0

 

:: VCHECK.cmd를 실행시켜 최신 버전의 정보 얻기
IF EXIST VCHECK.cmd call VCHECK.cmd

:: RunOnce 레지스트리 키값을 추가하여 다음 재부팅 때 VCHECK.cmd 파일 삭제하기

echo del /q "%~dp0VCHECK.cmd">%temp%\DEL.cmd
echo DEL /q %%0>>%temp%\DEL.cmd
Reg.exe add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v "del_vcheck" /t REG_SZ /d "%temp%\DEL.cmd" /f

: : 다운로드 받은 최신 버전 정보와 현재 파일의 버전정보 비교

:: 체크용 배치파일에 적혀있는 숫자보다 다운로드 받은 파일의 숫자가 더 크면 새 버전 알리기, 새 버전을 발견했다는 태그 만들어주기

IF %RELEASE_VER% GTR 1 echo .>NV.tag&goto NEW

:: 체크용 배치파일에 적혀있는 숫자와 다운로드 받은 파일의 숫자가 같으면 이미 최신버전이라고 알려주기
IF %RELEASE_VER% EQU 1 goto UTD

IF %RELEASE_VER% EQU 0 goto VCF

 

:NEW
echo 새로운 버전이 있습니다.

echo 아무 키나 누르면 윈도우 포럼으로 이동합니다.
pause

:: start 명령 뒤에 "" 를 붙이면 기본 연결 프로그램으로 실행시킵니다. 상대의 기본 브라우저가 익스라면 익스로..크롬이라면 크롬으로...

start "" https://windowsforum.kr

exit

 

:UTD
echo 현재 최신 버전을 사용중입니다.

echo 아무 키나 누르면 창이 닫힙니다.
pause

exit

 

:VCF

echo 버전 확인에 실패했습니다.

echo 아무 키나 누르면 창이 닫힙니다.
pause

exit

 

:SKIP_VCHECK

echo 이미 버전 확인을 했습니다.

echo.

pause

 

 

 

위와 같은 배치파일을 배포할 프로그램 내부에 심은 다음

프로그램을 업데이트 하였을 경우 드롭박스에 set RELEASE_VER=2 로 수정한 VCHECK.cmd를 업로드하면

사용자들에게 업데이트가 있음을 알려줄 수 있습니다.

 

즉, 프로그램을 실행할 때 지정된 숫자와 서버에서 다운로드 받은 파일의 숫자를 비교하고

서버에서 받은 숫자가 더 크다면 지정된 링크로 보내거나 다른 파일을 다운로드 받게 해주는 원리입니다.

 

물론 새로이 배포하는 프로그램에는 다음 버전 업데이트 감지를 위해 

IF %RELEASE_VER% GTR 2 goto NEW

IF %RELEASE_VER% EQU 2 goto UTD

이 두 비교문도 2로 바꿔서 배포해야겠죠.

 

===================================================================================

 

 

주의할점은 드롭박스 약관에 트래픽 제한이 있습니다.

일일 20GB, 10만회를 넘어가게되면 트래픽 제한이 걸립니다.

(원문

Traffic limits
Shared links and file requests are automatically banned if they generate unusually large amounts of traffic.

Dropbox Basic (free) accounts:

20 GB per day: The total amount of traffic that all of your links and file requests combined can generate
100,000 downloads per day: The total number of downloads that all of your links combined can generate

)

 

즉, 용량이 크거나 많은 사람에게 공유할 생각이라면 '알림'만 지원하고 

다운로드 자체는 그냥 본인 사이트 링크로 보내거나 다른 파일 공유 사이트로 보내는게 좋습니다.

MR→ATI.001

MR→ATI.002

MR→ATI.003